------- esercizio 2(a) -------

A := Mat([
	 [0, 2, 2],
	 [1, 4, 6],
	 [4, 8, 16]
	 ]);
-- riduco A
E1 := Mat([
	  [0, 1, 0],
	  [1, 0, 0],
	  [0, 0, 1]
	  ]);
E1*A;
E2 := Identity(3);  E2[3,1] := -4;  E2*E1*A;
E3 := Identity(3);  E3[3,2] := 4;  E3*E2*E1*A;
/*
 Mat([
  [1, 4, 6],
  [0, 2, 2],
  [0, 0, 0]
])
 */

------- esercizio 2(b) -------

B := Transposed(A)*A;  B;
-- calcolo una forma diagonale di B
E1 := Identity(3);  E1[2,1] := -36/17;
P := Transposed(E1);  Transposed(P) * B * P;
/*
Mat([
  [17, 0, 70],
  [0, 132/17, 132/17],
  [70, 132/17, 296]
])
*/
E2 := Identity(3); E2[3,1] := -70/17;
P := Transposed(E2*E1); Transposed(P) * B * P;
/*
Mat([
  [17, 0, 0],
  [0, 132/17, 132/17],
  [0, 132/17, 132/17]
])
*/
E3 := Identity(3); E3[3,2] := -1;
P := Transposed(E3*E2*E1); Transposed(P) * B * P;
/*
Mat([
  [17, 0, 0],
  [0, 132/17, 0],
  [0, 0, 0]
])
*/
MFE := P;
-- trovo v rispetto alla base F
MvF := Mat([[0],[0],[1]]);
Transposed(MvF) * (Transposed(MFE) * B * MFE) * MvF;
-- Calcolo le coordinate del vettore nel sistema originario:
MvE := MFE*MvF;  MvE;
-- Verifico che Q(v)=0:
Transposed(MvE) * B * MvF;

------- esercizio 2(c) -------

Transposed(MFE) * B * MFE;
-- La forma diagonale e' ordinata (quindi non devo usare matrici di scambio).
-- Devo normalizzare le entrate:
Define NR_Mat(M, L)
  Return Mat([[NR(Poly(X), L)|X In Riga]|Riga In M]);
EndDefine; -- NR_Mat

Use Q[a,b];
L := [a^2-17, b^2-132];
N := Mat([
	 [a/17, 0, 0],
	 [0, ab/132, 0],
	 [0, 0, 1]
	 ]);

MSE := MFE*N;
-- La forma canonica e':
NR_Mat(Transposed(MSE)*B*MSE, L);
-- e la matrice di trasformazione e'
MSE;
/*
Mat([
  [1/17a, -3/187ab, -2],
  [0, 1/132ab, -1],
  [0, 0, 1]
])
 */
-- Dove a = radq(17) e b = radq(132)

------- esercizio 3(a) -------

M_phiE_E := 1/7*Mat([
		    [-3, -12, -20],
		    [2, -13, -10],
		    [57, 81, 86]
		    ]);
M_phiE_E;
/*
Mat([
  [-3/7, -12/7, -20/7],
  [2/7, -13/7, -10/7],
  [57/7, 81/7, 86/7]
])
*/
-- Calcolo gli autovalori
Use Q[x];
D := Det(x*Identity(3) - M_phiE_E);  D;
-- Gli autovalori sono le soluzioni dell'equazione D = 0
Factor(D);
/*
[[x + 1, 1], [x - 3, 1], [x - 8, 1]]
*/
-- Gli autovalori sono -1, 3, 8

------- esercizio 3(b) -------

-- risolvo il sistema lineare omogeneo che ha matrice dei coefficienti B
B := (-1)*Identity(3) - M_phiE_E;  B;

E1 := Identity(3);  E1[2,1] := -1/2;  E1*B;
E2 := Identity(3);  E2[3,1] := -57/4;  E2*E1*B;
/*
Mat([
  [-4/7, 12/7, 20/7],
  [0, 0, 0],
  [0, -36, -54]
])
*/
E3 := Identity(3);  E3[1,3] := 1/21;  E3*E2*E1*B;
/*
Mat([
  [-4/7, 0, 2/7],
  [0, 0, 0],
  [0, -36, -54]
])
*/
E4 := Identity(3);  E4[1,1] := -7/4;  E4*E3*E2*E1*B;
E5 := Identity(3);  E5[3,3] := -1/36;  E5*E4*E3*E2*E1*B;
/*
Mat([
  [1, 0, -1/2],
  [0, 0, 0],
  [0, 1, 3/2]
])
*/
-- pongo z=t e ho x = 1/2 t e y = -3/2 t
-- L'autospazio di -1 e' { (1/2 t, -3/2 t, t) | t in R}
-- Quindi un vettore v che soddisfa la domanda e'
MvE := Mat([ [1/2], [-3/2], [1] ]);  MvE;
-- verifico:
M_phiE_E * MvE;